Option Strict On
Option Explicit On

Imports System
Imports System.Globalization
Imports System.Windows.Forms
Imports Nexamas.UI.Architecture
Imports Nexamas.UI.Components.ListPopup
Imports Nexamas.UI.Controls
Imports Nexamas.UI.FloatRuntime
Imports Nexamas.UI.General
Imports Nexamas.UI.Layout
Imports Nexamas.UI.Rendering
Imports Nexamas.UI.Theming
Imports Nexamas.UI.TextRendering
Imports Nexamas.UI.Composition
Imports Nexamas.UI.Values
Imports SkiaSharp

Namespace Nexamas.UI.Components

    Partial Public NotInheritable Class MASDatePicker
#Region "Pointer And Keyboard Interaction"

        Protected Overrides Sub OnMouseMove(ctx As MASThemeContext, ptPx As SKPoint)
            If Not Me.Enabled Then Return

            Dim rPx As SKRect = GetPixelBounds(ctx)
            Dim nowHover As Boolean = rPx.Contains(ptPx.X, ptPx.Y)

            If nowHover <> _hover Then
                _hover = nowHover
                InvalidateVisual()
            End If
        End Sub

        Protected Overrides Function OnMouseDown(ctx As MASThemeContext,
                                                 ptPx As SKPoint,
                                                 button As Integer) As Boolean
            If Not Me.Enabled Then Return False
            If button <> CInt(MouseButtons.Left) Then Return False

            Dim rPx As SKRect = GetPixelBounds(ctx)
            If Not rPx.Contains(ptPx.X, ptPx.Y) Then Return False

            RequestFocus()
            _pressed = True
            _hover = True
            InvalidateVisual()
            ToggleCalendar(ctx)
            Return True
        End Function

        Protected Overrides Function OnMouseUp(ctx As MASThemeContext,
                                               ptPx As SKPoint,
                                               button As Integer) As Boolean
            If _pressed Then
                _pressed = False
                InvalidateVisual()
                Return True
            End If

            Return False
        End Function

        Protected Overrides Sub OnMouseLeave(ctx As MASThemeContext)
            If _hover OrElse _pressed Then
                _hover = False
                _pressed = False
                InvalidateVisual()
            End If
        End Sub

        Protected Overrides Sub OnMouseCancel(ctx As MASThemeContext)
            _hover = False
            _pressed = False
            InvalidateVisual()
        End Sub

        Protected Overrides Sub OnHostLostFocus(ctx As MASThemeContext)
            If _isCalendarOpen Then
                CloseCalendarSafe()
                Return
            End If

            _hover = False
            _pressed = False
            InvalidateVisual()
        End Sub

        Protected Overrides Function OnKeyDown(ctx As MASThemeContext,
                                               keyCode As Keys) As Boolean
            If Not Enabled Then Return False

            Select Case keyCode
                Case Keys.Space, Keys.Enter, Keys.Down
                    RequestFocus()
                    _pressed = True
                    ToggleCalendar(ctx)
                    InvalidateVisual()
                    Return True

                Case Keys.Left
                    AdjustSelectedDate(-1)
                    Return True

                Case Keys.Right
                    AdjustSelectedDate(1)
                    Return True

                Case Keys.Up
                    AdjustSelectedDate(-7)
                    Return True

                Case Keys.PageUp
                    AdjustSelectedMonth(-1)
                    Return True

                Case Keys.PageDown
                    AdjustSelectedMonth(1)
                    Return True

                Case Keys.Home
                    MoveSelectedDateToBoundary(preferMinimum:=True)
                    Return True

                Case Keys.End
                    MoveSelectedDateToBoundary(preferMinimum:=False)
                    Return True

                Case Keys.Escape
                    If _isCalendarOpen Then
                        CloseCalendarSafe()
                        Return True
                    End If

                Case Keys.Delete, Keys.Back
                    If _selectedDate.HasValue Then
                        ClearDate()
                        Return True
                    End If
            End Select

            Return False
        End Function

        Protected Overrides Function WantsKeyboardFocus() As Boolean
            Return True
        End Function

#End Region

    End Class

End Namespace