Option Strict On
Option Explicit On

Imports System
Imports System.Collections.Generic
Imports System.Globalization
Imports System.Windows.Forms
Imports Nexamas.UI.Architecture
Imports Nexamas.UI.Composition
Imports Nexamas.UI.Controls
Imports Nexamas.UI.General
Imports Nexamas.UI.Layout
Imports Nexamas.UI.Rendering
Imports Nexamas.UI.TextRendering
Imports Nexamas.UI.Theming
Imports Nexamas.UI.Values
Imports SkiaSharp

Namespace Nexamas.UI.Components

    Partial Public NotInheritable Class MASDataForm

#Region "Layout"

        Friend Function GetPreferredLayoutSize(context As MASLayoutMeasureContext) As SKSize Implements IMASLayoutParticipant.GetPreferredLayoutSize
            Return MeasureIntrinsicSize(CreateSizeContext(context), SizeIntent).DesiredSize
        End Function

        Friend Function GetMinLayoutSize(context As MASLayoutMeasureContext) As SKSize Implements IMASLayoutParticipant.GetMinLayoutSize
            Return MeasureIntrinsicSize(CreateSizeContext(context), SizeIntent).MinSize
        End Function

        Friend Function MeasureIntrinsicSize(context As MASSizeContext,
                                             intent As MASSize) As MASSizeResult Implements IMASIntrinsicSizeContract.MeasureIntrinsicSize
            Dim safeContext As MASSizeContext = MASIntrinsicControlSizeMetrics.EnsureContext(context)
            Dim desiredHeight As Single = CalculateDesiredHeightDip()
            Dim desired As New SKSize(DataFormTokens.PreferredWidthDip, desiredHeight)
            Dim minimum As New SKSize(DataFormTokens.ContractMinWidthDip, DataFormTokens.MinHeightDip)
            Dim contentInset As New MASLayoutInset(DataFormTokens.PaddingHorizontalDip,
                                                   DataFormTokens.PaddingVerticalDip,
                                                   DataFormTokens.PaddingHorizontalDip,
                                                   DataFormTokens.PaddingVerticalDip)

            Return MASSizeResolver.FromMeasured(
                desiredSize:=desired,
                minSize:=minimum,
                maxSize:=New SKSize(DataFormTokens.MaxWidthDip, Single.PositiveInfinity),
                intent:=intent,
                context:=safeContext,
                canGrowWidth:=True,
                canGrowHeight:=True,
                contentInset:=contentInset,
                visualOverflowInset:=MASLayoutInset.Empty,
                hitOverflowInset:=MASLayoutInset.Empty,
                isFallback:=False)
        End Function

        Private Function CalculateDesiredHeightDip() As Single
            Dim height As Single = DataFormTokens.PaddingVerticalDip * 2.0F
            height += 24.0F
            If _description.Length > 0 Then height += DataFormTokens.HeaderGapDip + 20.0F
            height += DataFormTokens.SummaryGapDip + DataFormTokens.SummaryHeightDip
            height += DataFormTokens.HeaderBottomGapDip
            Dim count As Integer = Math.Max(1, _fields.Count)
            height += count * ResolveRowHeightDip()
            height += Math.Max(0, count - 1) * DataFormTokens.RowGapDip
            Return Math.Max(DataFormTokens.MinHeightDip, height)
        End Function

        Private Function ResolveRowHeightDip() As Single
            Return If(_compact, DataFormTokens.DenseRowHeightDip, DataFormTokens.RowHeightDip)
        End Function

        Private Shared Function CreateSizeContext(context As MASLayoutMeasureContext) As MASSizeContext
            If context Is Nothing Then Return MASIntrinsicControlSizeMetrics.EnsureContext(Nothing)
            Return context.ToSizeContext()
        End Function

#End Region

    End Class

End Namespace