Option Strict On
Option Explicit On

Imports System
Imports System.Windows.Forms
Imports System.Collections.Generic
Imports Nexamas.UI.Architecture
Imports Nexamas.UI.Composition
Imports Nexamas.UI.General
Imports Nexamas.UI.Layout
Imports Nexamas.UI.Rendering
Imports Nexamas.UI.TextRendering
Imports Nexamas.UI.Theming
Imports Nexamas.UI.Values
Imports SkiaSharp

Namespace Nexamas.UI.Controls

    Partial Public NotInheritable Class MASNotificationPanel

#Region "Layout / size"

        Friend Function GetPreferredLayoutSize(context As MASLayoutMeasureContext) As SKSize Implements IMASLayoutParticipant.GetPreferredLayoutSize
            Return MeasureIntrinsicSize(CreateSizeContext(context), SizeIntent).DesiredSize
        End Function

        Friend Function GetMinLayoutSize(context As MASLayoutMeasureContext) As SKSize Implements IMASLayoutParticipant.GetMinLayoutSize
            Return MeasureIntrinsicSize(CreateSizeContext(context), SizeIntent).MinSize
        End Function

        Friend Function MeasureIntrinsicSize(context As MASSizeContext,
                                             intent As MASSize) As MASSizeResult Implements IMASIntrinsicSizeContract.MeasureIntrinsicSize
            Dim safeContext As MASSizeContext = MASIntrinsicControlSizeMetrics.EnsureContext(context)
            Dim visibleRows As Integer = Math.Max(NotificationPanelTokens.MinimumVisibleRows, Math.Min(_items.Count, NotificationPanelTokens.DefaultVisibleRows))
            Dim rowAreaHeight As Single = If(_items.Count = 0,
                                             NotificationPanelTokens.EmptyStateHeightDip,
                                             visibleRows * NotificationPanelTokens.RowHeightDip + Math.Max(0, visibleRows - 1) * NotificationPanelTokens.RowGapDip)
            Dim desired As New SKSize(NotificationPanelTokens.DefaultWidthDip,
                                      NotificationPanelTokens.PaddingTopDip +
                                      NotificationPanelTokens.HeaderHeightDip +
                                      NotificationPanelTokens.HeaderContentGapDip +
                                      rowAreaHeight +
                                      NotificationPanelTokens.PaddingBottomDip)
            Dim minimum As New SKSize(NotificationPanelTokens.MinWidthDip, NotificationPanelTokens.MinHeightDip)
            Dim contentInset As New MASLayoutInset(NotificationPanelTokens.PaddingLeftDip,
                                                   NotificationPanelTokens.PaddingTopDip,
                                                   NotificationPanelTokens.PaddingRightDip,
                                                   NotificationPanelTokens.PaddingBottomDip)

            Return MASSizeResolver.FromMeasured(
                desiredSize:=desired,
                minSize:=minimum,
                maxSize:=New SKSize(Single.PositiveInfinity, Single.PositiveInfinity),
                intent:=MASSize.Normalize(intent),
                context:=safeContext,
                canGrowWidth:=True,
                canGrowHeight:=True,
                contentInset:=contentInset,
                visualOverflowInset:=MASLayoutInset.Empty,
                hitOverflowInset:=MASLayoutInset.Empty,
                isFallback:=False)
        End Function

        Private Shared Function CreateSizeContext(context As MASLayoutMeasureContext) As MASSizeContext
            If context Is Nothing Then Return MASIntrinsicControlSizeMetrics.EnsureContext(Nothing)
            Return context.ToSizeContext()
        End Function

#End Region
    End Class

End Namespace