Option Strict On
Option Explicit On

Imports System
Imports System.Collections.Generic
Imports System.Collections.ObjectModel
Imports System.Windows.Forms
Imports Nexamas.UI.Architecture
Imports Nexamas.UI.Composition
Imports Nexamas.UI.Controls
Imports Nexamas.UI.General
Imports Nexamas.UI.Layout
Imports Nexamas.UI.Rendering
Imports Nexamas.UI.TextRendering
Imports Nexamas.UI.Theming
Imports Nexamas.UI.Values
Imports SkiaSharp

Namespace Nexamas.UI.Components

    Partial Public NotInheritable Class MASMasterDetailView

#Region "Input"

        Protected Overrides Sub OnMouseMove(ctx As MASThemeContext,
                                            ptPx As SKPoint)
            Dim hit As MasterDetailItemHit = HitTest(ptPx)
            Dim index As Integer = If(hit Is Nothing, -1, hit.Index)
            If index = _hoverIndex Then Return
            _hoverIndex = index
            InvalidateVisual()
        End Sub

        Protected Overrides Function OnMouseDown(ctx As MASThemeContext,
                                                 ptPx As SKPoint,
                                                 button As Integer) As Boolean
            If button <> CInt(MouseButtons.Left) Then Return False
            Dim hit As MasterDetailItemHit = HitTest(ptPx)
            If hit Is Nothing Then Return _contentRect.Contains(ptPx.X, ptPx.Y)
            _pressedIndex = hit.Index
            InvalidateVisual()
            Return True
        End Function

        Protected Overrides Function OnMouseUp(ctx As MASThemeContext,
                                               ptPx As SKPoint,
                                               button As Integer) As Boolean
            If button <> CInt(MouseButtons.Left) Then Return False
            Dim pressed As Integer = _pressedIndex
            _pressedIndex = -1
            Dim hit As MasterDetailItemHit = HitTest(ptPx)
            If hit IsNot Nothing AndAlso hit.Index = pressed Then
                SetSelectedIndex(hit.Index, True)
                Return True
            End If
            InvalidateVisual()
            Return False
        End Function

        Protected Overrides Sub OnMouseLeave(ctx As MASThemeContext)
            _hoverIndex = -1
            _pressedIndex = -1
            InvalidateVisual()
        End Sub

        Protected Overrides Sub OnMouseCancel(ctx As MASThemeContext)
            _pressedIndex = -1
            InvalidateVisual()
        End Sub

        Protected Overrides Sub OnHostLostFocus(ctx As MASThemeContext)
            _pressedIndex = -1
            InvalidateVisual()
        End Sub

        Friend Overrides Function WantsPointerWheel(ctx As MASThemeContext,
                                                      ptPx As SKPoint) As Boolean
            Return Visible AndAlso Enabled AndAlso
                   _masterRect.Contains(ptPx.X, ptPx.Y) AndAlso
                   HasScrollableMasterViewport()
        End Function

        Friend Overrides Function CanHandlePointerWheel(ctx As MASThemeContext,
                                                        delta As Integer,
                                                        ptPx As SKPoint) As Boolean
            If delta = 0 OrElse Not WantsPointerWheel(ctx, ptPx) Then Return False
            Return CanScrollMasterViewport(delta)
        End Function

        Protected Overrides Sub OnMouseWheel(ctx As MASThemeContext,
                                             delta As Integer,
                                             ptPx As SKPoint)
            If Not CanScrollMasterViewport(delta) Then Return
            If delta < 0 Then
                _topIndex = Math.Min(ResolveMasterViewportMaxTop(), _topIndex + 1)
            ElseIf delta > 0 Then
                _topIndex = Math.Max(0, _topIndex - 1)
            End If
            InvalidateVisual()
        End Sub

        Protected Overrides Function OnKeyDown(ctx As MASThemeContext,
                                               keyCode As Keys) As Boolean
            If Not Enabled OrElse _items.Count = 0 Then Return False
            Select Case keyCode
                Case Keys.Up, Keys.Left
                    MoveBy(If(MASMasterDetailViewPolicy.ResolveRightToLeft() AndAlso keyCode = Keys.Left, 1, -1))
                    Return True
                Case Keys.Down, Keys.Right
                    MoveBy(If(MASMasterDetailViewPolicy.ResolveRightToLeft() AndAlso keyCode = Keys.Right, -1, 1))
                    Return True
                Case Keys.Home
                    SetSelectedIndex(0, True)
                    Return True
                Case Keys.End
                    SetSelectedIndex(_items.Count - 1, True)
                    Return True
                Case Keys.PageUp
                    MoveBy(-Math.Max(1, _lastVisibleCount))
                    Return True
                Case Keys.PageDown
                    MoveBy(Math.Max(1, _lastVisibleCount))
                    Return True
            End Select
            Return False
        End Function

        Protected Overrides Function WantsKeyboardFocus() As Boolean
            Return Visible AndAlso Enabled
        End Function

        Protected Overrides Function WantsPointerFocus() As Boolean
            Return False
        End Function

#End Region

    End Class

End Namespace